// This macro runs the particle analyzer on an an image
// that has particles with holes and compares the results
// to those from measuring the ROIs in the overlay
// created by the particle analyzer. Correct measurement 
// of the ROIs requires that the threshold is set and
// the "Limit to threshold" option is enabled.

  saveSettings;
  tolerance = 0.0000001;
  labels = newArray("Area","Mean","StdDev","Min","Max", "X","Y",
    "XM","YM","Perim.","Major","Angle", "Circ.","Feret");
  run("AuPbSn 40 (56K)");
  run("Set Measurements...", "area mean standard min centroid perimeter fit feret's");
  setAutoThreshold("Huang");
  run("Analyze Particles...", "  show=Overlay clear");
  //resetThreshold;
  for (i=0; i<nResults; i++) {
     Overlay.activateSelection(i);
     for (j=0; j<labels.length; j++) {
        label = labels[j];
        List.setMeasurements("limit");
        v1 = getResult(label,i);
        v2 = List.getValue(label);
        if (abs(v1-v2)>tolerance || (!isNaN(v1)&&isNaN(v2)) )
           print(label+"["+i+"]: "+v1+"  "+v2);

     }
  }
  restoreSettings;