/*Makes grid based on multi-purpose grid from Gundersen & Jensen 
(J Microsc. 1987, 147:229-6) for stereology quantification as 
non-destructive overlay. 
Options include lines and crosses of differnet density.
Do not forget to "Set Scale" to get correct printout of grid parameters.
Parameters of the grid are reflected in "Multipurpose grid parameters" text window.
 
Version: 0.1
Date: 14/08/2011
Author: Aleksandr Mironov amj-box@mail.ru
*/

//Initial dialog
Dialog.create("Multipurpose stereological grid"); 
Dialog.addMessage("Version: 0.1");
Dialog.addMessage("Based on multipurpose grid from \nGundersen & Jensen, J Microsc. 1987, 147:229-6");
Dialog.addMessage("Please, set scale for correct measurements");
Dialog.addMessage("\n ");
Dialog.setInsets(0, 20, 0);
Dialog.addChoice("Set grid dimensions:", newArray("by tiles density", "by area per point"));
Dialog.addMessage("Grid tile includes 4 regular points and 2 segmented lines");
Dialog.show();
dimensions = Dialog.getChoice();
getPixelSize(unit, pw, ph, pd);

//Main dialog box
Dialog.create("Grid parameters"); 
Dialog.addMessage("          GENERAL:");
Dialog.addCheckbox("Random Offset", true);
Dialog.addCheckbox("New Overlay", true);
Dialog.addNumber("Line thickness =", 1,0,2,"pixels");
if (dimensions=="by tiles density") { 
	Dialog.addNumber("Tile* density  =", 3,0,2,"per short side"); 
	} else { 
	Dialog.addNumber("Area per point  =", 10000,2,8," "+unit+"^2"); 
	}; 
Dialog.addMessage("          TEST POINTS:");
Dialog.addCheckbox("Encircled Points (1/4 of regular)", true);
Dialog.addCheckbox("Dense Points (x4 of regular)", true);
Dialog.addChoice("Regular points color:", newArray("cyan", "red", "yellow", "green", "blue", "magenta", "orange", "black", "white"));
Dialog.addChoice("Dense points color:", newArray("green", "yellow", "red", "blue", "cyan", "magenta", "orange", "black", "white"));
Dialog.addMessage("          TEST LINES:");
Dialog.addCheckbox("Horizontal segmented", true);
Dialog.addCheckbox("Vertical segmented", false);
Dialog.addCheckbox("Horizontal solid (x3 of segmented)", false);
Dialog.addCheckbox("Vertical solid (x3 of segmented)", false);
Dialog.addChoice("Line color:", newArray("cyan", "red", "green", "magenta", "blue", "yellow", "orange", "black", "white")); 
Dialog.addMessage("==========================================");
Dialog.addMessage("*Tile includes 4 regular points and 2 segmented lines");
Dialog.show(); 
 
//grid parameters 
offset = Dialog.getCheckbox();
new = Dialog.getCheckbox();
t = Dialog.getNumber();
dimens = Dialog.getNumber();
circ = Dialog.getCheckbox();
dense = Dialog.getCheckbox();
rpcolor = Dialog.getChoice(); 
dpcolor = Dialog.getChoice();
hor_seg = Dialog.getCheckbox();
ver_seg = Dialog.getCheckbox();
hor_sol = Dialog.getCheckbox();
ver_sol= Dialog.getCheckbox();
lcolor = Dialog.getChoice();

//initial settings for l/p
vsg=hsg=vsl=hsl=0;

//tile size
getDimensions(width, height, channels, slices, frames);
if (dimensions=="by tiles density") {
	if (width>=height) { 
	ss = height; 
	} else { 
	ss = width; 
	} 
	tileside = ss/dimens;
	}else {
	tileside = sqrt(4*dimens/ph/pw);
	}
pointd = tileside/4;
pointr = tileside/2;

//check overlay
if (new == true) run("Remove Overlay");

//creating random offset 
off1 = random; 
off2 = random; 
if (offset == false) off1 = off2 = 0.5; 
xoff = round(pointd*off1);
yoff = round(pointd*off2);
 
//Horizonal solid lines
if (hor_sol == true){
	y = yoff;
	while (true && y<height) { 
		makeLine(0, y, width, y);
		run("Add Selection...", "width="+t+" stroke="+lcolor);
		y += pointr;
		}
	run("Select None");
	hsl = 2;
	}

//Vertical solid lines
if (ver_sol == true){
	x = xoff;
	while (true && x<width) { 
		makeLine(x, 0, x, height);
		run("Add Selection...", "width="+t+" stroke="+lcolor);
		x += pointr;
		}
	run("Select None");
	vsl = 2;
	}

//Horizonal segmented lines
if (hor_seg == true){
hsg = 1;

//Y loop1
y1 = yoff;
while (y1<height) { 
		
		//X loop1
		x1 = xoff; 
		while (x1<width) {   
			makeLine(x1, y1, x1+pointr, y1);
			run("Add Selection...", "width="+t+" stroke="+lcolor);
			x1 += tileside;  
		} 
	y1 += tileside;  
	run("Select None");
	}
	
//Y loop2
y1 = yoff+pointr;
while (y1<height) { 
 
		//X loop2 
		x2 = xoff;
		x1 = 0;	
		while (x1<width) {   
			makeLine(x1, y1, x2, y1);
			run("Add Selection...", "width="+t+" stroke="+lcolor);
			x1 = x2 + pointr;
			x2 += tileside;
		} 
	y1 += tileside;  
	run("Select None");
	}
}

//Vertical segmented lines
if (ver_seg == true){
vsg = 1;

//X loop1
x1 = xoff;
while (x1<width) { 
		
		//Y loop1
		y1 = yoff; 
		while (y1<height) {   
			makeLine(x1, y1, x1, y1+pointr);
			run("Add Selection...", "width="+t+" stroke="+lcolor);
			y1 += tileside;  
		} 
	x1 += tileside;  
	run("Select None");
	}
	
//X loop2
x1 = xoff+pointr;
while (x1<width) { 
 
		//Y loop2 
		y2 = yoff;
		y1 = 0;	
		while (y1<height) {   
			makeLine(x1, y1, x1, y2);
			run("Add Selection...", "width="+t+" stroke="+lcolor);
			y1 = y2 + pointr;
			y2 += tileside;
		} 
	x1 += tileside;  
	run("Select None");
	}
}
	
 //Regular points

//Initial coordinates X
x1 = xoff;
x2 = x1 - pointd/16; 
x3 = x1 + pointd/16;

//X loop 
while (x1<width) { 
 
		//initial coordinates Y 
		y1 = yoff; 
		y2 = y1 - pointd/16; 
		y3 = y1 + pointd/16; 

		//Y loop 
		while (y1<height) {  
		 
			//horizontal line	 
			makeLine(x2,y1,x3,y1); 
			run("Add Selection...", "width="+t+" stroke="+rpcolor); 
			//vertical line 
			makeLine(x1,y2,x1,y3); 
			run("Add Selection...", "width="+t+" stroke="+rpcolor); 
			
		y1 += pointr; 
		y2 += pointr; 
		y3 += pointr; 
		} 
	x1 += pointr; 
	x2 += pointr; 
	x3 += pointr; 
	run("Select None");
	} 

//Dense points 
if (dense == true){
	//Initial coordinates X;
	x1 = xoff - pointd/2;
	x2 = x1 - pointd/16; 
	x3 = x1 + pointd/16;
	
	//X loop 
	while (x1<width) { 
 
		//initial coordinates Y 
		y1 = yoff - pointd/2; 
		y2 = y1 - pointd/16; 
		y3 = y1 + pointd/16;
		 
		//Y loop 
		while (y1<height) {  
			//horizontal line	 
			makeLine(x2,y1,x3,y1); 
			run("Add Selection...", "width="+t+" stroke="+dpcolor); 
			//vertical line 
			makeLine(x1,y2,x1,y3); 
			run("Add Selection...", "width="+t+" stroke="+dpcolor); 
		y1 += pointd; 
		y2 += pointd; 
		y3 += pointd; 
		} 
	x1 += pointd; 
	x2 += pointd; 
	x3 += pointd; 
	} 
	run("Select None");
}

//Encircled points
if (circ == true){
	
	//Initial coordinates X
	x1 = xoff;
	x2 = x1 - pointd/16;
	
	//X loop 
	while (x2<width) { 
 
		//Initial coordinates Y 
		y1 = yoff; 
		y2 = y1 - pointd/16; 
		 
		//Y loop 
		while (y2<height) {  
			makeOval(x2, y2, pointd/8, pointd/8);
			run("Add Selection...", "width="+t+" stroke="+lcolor); 
		y2 += tileside;  
		}  
	x2 += tileside;  
	} 
	run("Select None");
}

//  Printing the parameters of the grid
	name = getTitle();	
	window = isOpen("Multipurpose grid parameters"); 
	title = "[Multipurpose grid parameters]"; 
	
	if (window == false){  
	run("Text Window...", "name="+ title +"width=60 height=20 menu"); 
	setLocation(0, 0); 
	} ;
	
	print(title, "\n Grid for sample ["+name+"]"); 
	print(title, "\n"); 
	print(title, "\n Image size = "+width+"x"+height+" pixels");
	print(title, "\n Pixel size = "+pw+" "+unit);
	print(title, "\n Scale = "+1/pw+" pixels/"+unit);
	print(title, "\n ");
	 
	print(title, "\n Area per regular point ="+tileside*tileside*pw*ph/4+"  "+unit+"^2");
	if (dense == true){ 
		n = 16;
		}else{
		n = 0;
		}
	if (circ == true){ 
	print(title, "\n Area per encircled point ="+tileside*tileside*pw*ph+"  "+unit+"^2"); 
	};
	print(title, "\n Area per any point ="+tileside*tileside*pw*ph/(4+n)+"  "+unit+"^2");
	print(title, "\n");
	
	if (ver_seg && ver_sol == true)
	vsg = 0; 
	if (hor_seg && hor_sol == true)
	hsg = 0; 
	z = vsg+hsg+vsl+hsl;
	lp = pw*tileside*z;
	if (hor_seg || ver_seg ||hor_sol || hor_sol == true){
		print(title, "\n Test line per any point(l/p) ="+lp/(4+n)+"  "+unit);
			if (circ == true){
			print(title, "\n Test line per encircled point(l/p) ="+lp+"  "+unit);
			}
			if (hor_seg || ver_seg ||hor_sol || hor_sol == true){
			print(title, "\n Test line per regular point(l/p) ="+lp/4+"  "+unit);
			}
		}
	print(title, "\n _______________________");
	print(title, "\n ");